10 PRINT CHR$(27);"[2J"
20 PRINT TAB(33);"ROCKET"
30 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
40 PRINT TAB(16);"SUPPORTS QUEST SUPER BASIC V6 AND ABOVE"
50 PRINT
60 PRINT TAB(24);"LUNAR LANDING SIMULATION"
70 PRINT TAB(24);"----- ------- ----------"
80 PRINT
90 INPUT "DO YOU WANT INSTRUCTIONS (YES OR NO)"A$
100 IF A$="NO" GOTO 340
110 PRINT
120 PRINT "YOU ARE LANDING ON THE MOON AND AND HAVE TAKEN OVER MANUAL CONTROL 1000 FEET"
130 PRINT "ABOVE A GOOD LANDING SPOT. YOU HAVE A DOWN-WARD VELOCITY OF 50 FEET/SEC. 150"
140 PRINT "UNITS OF FUEL REMAIN."
150 PRINT
160 PRINT "HERE ARE THE RULES THAT GOVERN YOUR APOLLO SPACE-CRAFT:"
170 PRINT
180 PRINT "1. AFTER EACH SECOND THE HEIGHT, VELOCITY, AND REMAINING FUEL WILL BE REPORTED"
190 PRINT "   VIA DIGBY YOUR ON-BOARD COMPUTER."
200 PRINT
210 PRINT "2. AFTER THE REPORT A '?' WILL APPEAR. ENTER THE NUMBER OF UNITS OF FUEL YOU"
220 PRINT "   WISH TO BURN DURING THE NEXT SECOND. EACH UNIT OF FUEL WILL SLOW YOUR"
230 PRINT "   DESCENT BY 1 FOOT/SEC."
240 PRINT
250 PRINT "3. THE MAXIMUM THRUST OF YOUR ENGINE IS 30 FEET/SEC/SEC OR 30 UNITS OF FUEL"
260 PRINT "   PER SECOND."
270 PRINT
280 PRINT "4. WHEN YOU CONTACT THE LUNAR SURFACE. YOUR DESCENT ENGINE WILL AUTOMATICALLY"
290 PRINT "   SHUT DOWN AND YOU WILL BE GIVEN A REPORT OF YOUR LANDING SPEED AND REMAINING"
300 PRINT "   FUEL."
310 PRINT
320 PRINT "5. IF YOU RUN OUT OF FUEL THE '?' WILL NO LONGER APPEAR BUT YOUR SECOND BY"
330 PRINT "   SECOND REPORT WILL CONTINUE UNTIL YOU CONTACT THE LUNAR SURFACE."
340 PRINT
350 PRINT "BEGINNING LANDING PROCEDURE.........."
360 PRINT "G O O D  L U C K ! ! !"
370 PRINT
380 PRINT "SEC...FEET......SPEED.....FUEL.....PLOT OF DISTANCE............................."
390 LET T=0
400 LET H=1000
410 LET V=50
420 LET F=150
430 LET X=36+(H/25)
440 PRINT T;TAB(6);H;TAB(16);V;TAB(26);F;TAB(35);"I";TAB(X);"*";
450 INPUT B
460 IF B<0 GOTO 600
470 IF B>30 GOTO B=30
480 IF B>F THEN LET B=F
490 LET Z=V-B+5
500 LET F=F-B
510 LET H=H-0.5*(V+Z)
520 IF H<=0 GOTO 620
530 LET T=T+1
540 LET V=Z
550 IF F>0 GOTO 430
560 IF B=0 GOTO 580
570 PRINT"**** OUT OF FUEL ****"
580 LET X=36+(H/25)
590 PRINT T;TAB(6);H;TAB(16);V;TAB(26);F;TAB(35);"I";TAB(X);"*"
600 LET B=0
610 GOTO 490
620 PRINT "......CONTACT..................................................................."
630 LET H=H+0.5*(Z+V)
640 IF B=5 GOTO 670
650 LET D=(-V+SQR(V*V+H*(10-2*B)))/(5-B)
660 GOTO 680
670 LET D=H/V
680 LET Z=V+(5-B)*D
690 PRINT
700 PRINT "TOUCHDOWN AT ";T+D;" SECONDS."
710 PRINT "LANDING VELOCITY=";Z;" FEET/SEC."
720 PRINT F;" UNITS OF FUEL REMAINING."
730 IF Z<>0 GOTO 760
740 PRINT "CONGRATULATIONS! A PERFECT LANDING!!"
750 PRINT "YOUR LICENSE WILL BE RENEWED.......LATER."
760 IF ABS(Z)<2 GOTO 790
770 PRINT "***** SORRY, BUT YOU BLEW IT!!!!"
780 PRINT "APPROPRIATE CONDOLENCES WILL BE SENT TO YOUR NEXT OF KIN."
790 PRINT
800 PRINT
810 PRINT
820 INPUT "ANOTHER MISSION"A$
830 IF A$="YES" GOTO 340
840 PRINT
850 PRINT "CONTROL OUT."
860 PRINT
870 END