5 DEFINT Z
10 LET G=19:LET N=6
20 GOSUB 5040
30 GOSUB 5010
40 GOSUB 3000
50 LET X=0:LET Y=0:LET Z=0
60 LET A=RND(G):LET B=RND(G):LET C=RND(G)
70 GOSUB 5010
80 FOR D=1 TO N STEP 1
90 GOSUB 1000
100 GOSUB 2000
110 IF X=A THEN IF Y=B THEN IF Z=C GOTO 300
120 GOSUB 500
130 NEXT D
140 GOSUB 5010
150 PRINT "YOU HAVE BEEN TORPEDOED!  ABANDON SHIP!"
160 PRINT "THE SUBMARINE WAS AT ";A;",";B;",";C:GOTO 400
300 PRINT :PRINT "B O O M ! ! YOU FOUND IT IN ";D;" TRIES!"
400 PRINT :PRINT :INPUT "ANOTHER GAME (Y OR N)"A$
410 IF A$="Y"GOTO 50
420 PRINT "OK.  HOPE YOU ENJOYED YOURSELF.":GOTO 700
500 R=3:L=1:T$="SONAR REPORT: ":GOSUB 5070
510 IF Y>B THEN PRINT "NORTH";
520 IF Y<B THEN PRINT "SOUTH";
530 IF X>A THEN PRINT "EAST";
540 IF X<A THEN PRINT "WEST";
550 IF Y<>B THEN PRINT " AND";
555 IF X<>A THEN PRINT " AND";
560 IF Z>C THEN PRINT " TOO LOW."
570 IF Z<C THEN PRINT " TOO HIGH."
580 IF Z=C THEN PRINT " DEPTH OK.";CHR$(7)
590 IF X=A THEN PRINT CHR$(7)
600 IF Y=B THEN PRINT CHR$(7)10,10
610 RETURN
700 GOSUB 5050
710 END
1000 REM  ** UPDATE SCREEN DATA **
1010 R=1:L=1:GOSUB 5060
1020 PRINT "================================================================================"
1030 R=2:L=1:T$="SHOTS FIRED: ":GOSUB 5070
1040 PRINT D-1
1050 R=2:L=48:T$="LAST SHOT X=":GOSUB 5070
1060 PRINT X;" Y=";Y;"    DEPTH=";Z
1065 PRINT
1070 PRINT "================================================================================"
1080 RETURN
2000 REM  ** GET USER INPUT **
2010 GOSUB 5050
2020 R=6:L=1:T$="ENTER SURFACE COORDINATES (X,Y): ":GOSUB 5070:INPUT X,Y
2030 R=7:L=17:T$="ENTER DEPTH (Z): ":GOSUB 5070:INPUT Z
2040 GOSUB 5040
2050 RETURN
3000 REM  ** INTRO **
3010 PRINT "DEPTH CHARGE - Super BASIC VERSION"
3020 WAIT(300)
3030 GOSUB 5010
3040 PRINT "================================================================================"
3050 PRINT "YOU ARE THE CAPTAIN OF THE DESTROYER USS COSMAC ELF AN ENEMY SUB HAS BEEN"
3060 PRINT "CAUSING YOU TROUBLE.  YOUR MISSION IS TO DESTROY IT.  YOU HAVE ";N;" SHOTS."
3070 PRINT
3080 PRINT "YOUR SONAR OFFICER KNOWS THAT THE SUB IN SOMEWHERE WITHIN A 0-";G;" BY 0-";
3095 PRINT G;" GRID."
3090 PRINT "SPECIFY DEPTH CHARGE EXPLOSION POINT WITH A TRIO OF NUMBERS"
3110 PRINT "  -- THE FIRST TWO ARE THE SURFACE COORDINATES"
3120 PRINT "  -- THE THIRD IS THE DEPTH"
3130 PRINT
3140 PRINT "GOOD LUCK!"
3150 PRINT "================================================================================"
3160 INPUT "HIT ENTER TO CONTINUE..."Q$
3170 RETURN
5000 REM ** VT100 CURSOR CONTROL SUBROUTINES **
5010 GOSUB 5030:GOSUB 5020:RETURN
5020 PRINT CHR$(27);"[2J";:RETURN
5030 PRINT CHR$(27);"[H";:RETURN
5040 PRINT CHR$(27);"[?25l";:RETURN
5050 PRINT CHR$(27);"[?25h";:RETURN
5060 PRINT CHR$(27);"[";R;";";L;"H";:RETURN
5070 PRINT CHR$(27);"[";R;";";L;"H";CHR$(27);"[K";T$;:RETURN