5 GOSUB 5010
10 PRINT "========================================================================"
15 PRINT "                               23 MATCHES"
20 PRINT "               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
25 PRINT "    Optimized for CDP1802 based COSMAC Elf systems using RC/BASIC-L2"
30 PRINT "                        SupportS VT100 terminals"
35 PRINT "========================================================================"
40 PRINT:PRINT "INSTRUCITONS:":PRINT
45 PRINT "This game is a game called '23 MATCHES'."
50 PRINT
60 PRINT "When it is your turn, you may take one, two or three matches. The Object"
70 PRINT "of the game is not to have to take the last match."
80 PRINT "THE LAST MATCH."
90 PRINT
100 PRINT:PRINT "========================================================================"
110 INPUT "HIT ENTER WHEN READY TO PLAY";Q$
120 GOSUB 5010
130 PRINT "Let's flip a coin to see who goes first. If it comes up heads, I win."
140 LET N=23
150 IF RND(10) > 5 GOTO 190
160 PRINT "TAILS! YOU GO FIRST. "
170 PRINT
180 GOTO 300
190 PRINT "HEADS! I WIN! HA! HA!"
200 PRINT "PREPARE TO LOSE, MEATBALL-NOSE!!"
210 PRINT
220 PRINT "I TAKE 2 MATCHES"
230 LET N=N-2
270 PRINT "THE NUMBER OF MATCHES IS NOW ";N
280 PRINT
290 PRINT "YOUR TURN -- YOU MAY TAKE 1, 2 OR 3 MATCHES."
300 INPUT "HOW MANY DO YOU WISH TO REMOVE";K
310 IF K > 3 GOTO 510
320 IF K <= 0 GOTO 510
330 LET N=N-K
340 PRINT "THERE ARE NOW ";N;" MATCHES REMAINING."
350 IF N = 4 GOTO 420
360 IF N = 3 GOTO 440
370 IF N = 2 GOTO 460
380 IF N <= 1 GOTO 610
390 LET Z=4-K
400 GOTO 470
410 PRINT
420 LET Z=3
430 GOTO 470
440 LET Z=2
450 GOTO 470
460 LET Z=1
470 PRINT "MY TURN! I REMOVE ";Z;" MATCHES"
480 LET N=N-Z
490 IF N <= 1 GOTO 550
500 GOTO 270
510 PRINT "VERY FUNNY! DUMMY!"
520 PRINT "DO YOU WANT TO PLAY OR GOOF AROUND?"
540 GOTO 300
550 PRINT
560 PRINT"YOU POOR BOOB! YOU TOOK THE LAST MATCH! I GOTCHA!!"
570 PRINT "HA! HA! I BEAT YOU!!!"
580 PRINT
590 PRINT "GOOD BYE LOSER!"
600 GOTO 640
610 PRINT "YOU WON, FLOPPY EARS!"
620 PRINT "THINK YOU'RE PRETTY SMART!"
630 PRINT "LETS PLAY AGAIN AND I'LL BLOW YOUR SHOES OFF!!"
640 INPUT "ANOTHER GAME (Y/N)";Q$
650 IF Q$="Y"GOTO 120
660 PRINT :PRINT :PRINT "THANK YOU FOR PLAYING."
670 END
5000 REM ** VT100 CONTROL ROUTINES **
5010 REM ** CLEAR SCREEN AND HOME
5020 GOSUB 5050
5030 GOSUB 5080
5040 RETURN
5050 REM ** HOME SCREEN **
5060 PRINT CHR$(27);"[H";
5070 RETURN
5080 REM ** CLEAR SCREEN **
5090 PRINT CHR$(27);"[2J";
5100 RETURN